Наши рекомендации:

3.3 Создаем простой советник с сеткой ордеров по системе Мартингейл

Содержание

Всем доброго времени суток!

Многие люди отрицают возможность заработать на Форекс по системе усреднения и Мартингейла. Они называют данный подход рулеткой, сливатором или кочергой. Часть активных пользователей, только заметив это название в топике темы, тут же бегут писать свой гневный коммент о том, что это лохотрон и подход дилетантов.

Советник Форекс Мартингейл

Как бы вы не относились к идее сеточной торговли, не стоит игнорировать тот факт, что в умелых руках с правильно настроенным риском, данная система способна показывать стабильный результат на протяжении многих лет. Часть из представленных ПАММ счетов и сигналов нашей команды подтверждают этот факт.

Если же вы не знаете, что такое Мартингейл, то пришло время познать что-то новое!

На этом уроке мы научимся создавать простой советник по системе Мартингейл с фиксированным шагом ордеров и небольшим набором настроек. Текста будет много, но иначе, к сожалению, никак. С каждым новым уроком становится все сложнее описывать всю ту вакханалию, которая происходит в редакторе Meta Editor. Тем временем размер советника, создаваемого в этом уроке составляет уже 300 строк, что уже можно считать серьезной, полноценной программой.

Описание торговой логики работы советника

Для того, чтобы не открывать беспорядочно сделки в разные стороны, данный советник будет осуществлять вход первого ордера сетки по сигналу индикатора. Для разнообразия в этом уроке я решил примерить классический индикатор MACD. Суть стратегии поражает своей простотой. Мы будем входить в покупки, как только гистограмма MACD пересечет нулевую отметку снизу вверх и закрепиться за ней. Продажи, соответственно, происходят зеркально, когда индикатор опускается ниже отметки 0. Период советника будет М15.

Стоп Лосса у данной системы нет. Если цена идет в нашу сторону — сделка закрывается по Тейк Профиту и советник переходит в состояние ожидания нового сигнала. Если же цена настроена против нас, то в работу включается блог построения сетки с функцией Мартингейла. Т.е. когда цена проходит X пунктов против направления ордера — открывается дополнительная сделка в этом же направлении с увеличенным лотом. Шаг ордеров такой сетки будет фиксированным и задается в настройках.

Чтобы усложнить программирование в советнике будет также две дополнительных фишки — перевод ТП всех ордеров в безубыток при достижении N колена, чтобы снизить риск и скорее закрыть затяжную сетку. А также настройка запуска усреднения, при которой лот будущий ордеров перестанет увеличиваться, чтобы снизить нагрузку на маржу.

Обе сетки на покупку и продажу будут работать независимо друг от друга.

Начинаем писать программный код

Создаем новый советник, указываем ему имя, автора, ссылку. Задавать параметры и обработчики событий не нужно, жмем Далее — Готово.

Присоединяем к коду встроенную библиотеку для расшифровки ошибок. При тестировании она поможет находить ваши недочеты и выдаст конкретный текст ошибки на английском языке.

//+------------------------------------------------------------------+
//|                                         3.4 Simple martingale EA |
//|                                   Copyright (c) DaVinci FX Group |
//|                                      https://www.davinci-fx.com/ |
//+------------------------------------------------------------------+
#property copyright "Copyright (c) DaVinci FX Group"
#property link      "https://www.davinci-fx.com/"
#property version   "1.00"
#property strict

#include <..\Libraries\stdlib.mq4> //библиотека для расшифровки ошибок

//+------------------------------------------------------------------+

//| 3.4 Simple martingale EA |

//| Copyright (c) DaVinci FX Group |

//| https://www.davinci-fx.com/ |

//+------------------------------------------------------------------+

#property copyright "Copyright (c) DaVinci FX Group"

#property link "https://www.davinci-fx.com/"

#property version "1.00"

#property strict

#include <..\Libraries\stdlib.mq4> //библиотека для расшифровки ошибок

Теперь нам нужно задать внешние переменные, чтобы более гибко управлять советником и иметь возможность его оптимизировать. Я разбил все настройки на три блока:

Основные настройки перекочевали из предыдущих уроков, тут все понятно. Торговый лот, который будет использоваться для первого ордера сетки, максимальное проскальзывание, Тейк Профит сетки ордеров, комментарий к ордеру и магик номер всех ордеров советника.

extern string s0 = "<== General Settings ==>"; //>  >  >
extern double  Lot                  = 0.01;  //Start lot
extern int     Slippage             = 5;
extern double  TakeProfit           = 15;
extern string  Comments             = "DaVinci EA";
extern int     MagicNumber          = 654321;

extern string s0 = "<== General Settings ==>"; //> > >

extern double Lot = 0.01; //Start lot

extern int Slippage = 5;

extern double TakeProfit = 15;

extern string Comments = "DaVinci EA";

extern int MagicNumber = 654321;

Настройки индикатора MACD. Он имеет три параметра: быстрая, медленная скользящая и сигнальная. Их все мы переносим в советник

extern string s1 = "<== Indicator Settings ==>"; //>  >  >
extern int     InpFastEMA           = 12;    //Fast EMA Period
extern int     InpSlowEMA           = 26;    //Slow EMA Period
extern int     InpSignalSMA         = 9;     //Signal SMA Period

extern string s1 = "<== Indicator Settings ==>"; //> > >

extern int InpFastEMA = 12; //Fast EMA Period

extern int InpSlowEMA = 26; //Slow EMA Period

extern int InpSignalSMA = 9; //Signal SMA Period

Настройки работы сетки ордеров. Вначале мы должны задать расстояние от последнего ордера, пройдя которое советник отроет следующее колено сетки. Т.е. шаг сетки Grid Distance будет задан строго в пунктах и строиться она будет только, если цена будет идти против направления торговли. Следующий параметр Lot Multiplier будет отвечать за множитель лота для каждого последующего колена, это и есть работа мартингейла. Далее задаем номер колена, на котором увеличение торгового лота будет отключено Averaging Level дабы снизить риск маржин колла. Последние два параметра будут отвечать за безубыток всей сетки. Breakeven Level — номер колена, на котором ТП сетки больше не учитывается и она переводится в безубыток с целью уменьшить риск, когда в рынке уже достаточно колен. Параметр Breakeven Step же осуществляет отступ в пунктах от уровня БУ. Нужно заметить, что он может быть отрицательного значения.

extern string s2 = "<== Grid Settings ==>"; //>  >  >
extern double  GridDistance         = 20;    //Grid Distance
extern double  Multiplier           = 2;     //Lot Multiplier            
extern int     Averaging_Level      = 7;     //Averaging Level
extern int     BE_Level             = 5;     //Breakeven Level
extern double  BE_Step              = 1;     //Breakeven Step

extern string s2 = "<== Grid Settings ==>"; //> > >

extern double GridDistance = 20; //Grid Distance

extern double Multiplier = 2; //Lot Multiplier

extern int Averaging_Level = 7; //Averaging Level

extern int BE_Level = 5; //Breakeven Level

extern double BE_Step = 1; //Breakeven Step

Ниже добавим переменную локального уровня Update_Time для запоминания времени открытия текущей свечи. Также для работы с сеткой я предпочитаю использовать структуру — набор элементов произвольного типа. В справке есть подробное описание, как она работает и по сути тут нет ничего сложного. Структура это набор определенного количества параметров под определенным именем структуры.

datetime Update_Time = 0;

struct SetkaEnv{
   int      count_buy;
   int      count_sell;
   datetime lasttimeB, lasttimeS;
   double   last_distanceB, last_distanceS;
   double   firstlotB, firstlotS;
   double   lastlotB, lastlotS;
   double   avgB, avgS;
};
SetkaEnv env;

datetime Update_Time = 0;

struct SetkaEnv{

int count_buy;

int count_sell;

datetime lasttimeB, lasttimeS;

double last_distanceB, last_distanceS;

double firstlotB, firstlotS;

double lastlotB, lastlotS;

double avgB, avgS;

};

SetkaEnv env;

Выше мы объявили структуру под именем SetkaEnv. Внутри ее тела находится 11 элементов, которые нам будут нужны для работы сеточного советника:

count_buy, count_sell — подсчет количества ордеров сетки в обоих направлениях
lasttimeB, lasttimeS — время открытия последнего ордера сетки отдельно для Buy и Sell
last_distanceB, last_distanceS — расстояние от текущей цены до цены открытия последнего ордера сетки отдельно для покупок и продаж.
firstlotB, firstlotS — значения самого малого лота у ордера сетки, т.е. первого.
lastlotB, lastlotS — значения лота последнего открытого ордера сетки, т.е. самого крупного
avgB, avgS — переменные, которые будет содержать в себе ценовое значение безубытка обеих сеток на покупку и продажу.

После создания структуры ее необходимо проинициализировать строчкой SetkaEnv env;

Все, структура готова к работе. Теперь, чтобы получить количество ордеров на покупку мы просто прописываем в коде env.count_buy. Точка «.» между словами обозначает, что переменная count_buy принадлежит структуре.

Переменные в структуре ничем не отличаются от обычных. Вы можете также просто объявить double переменную count_buy и записывать в нее значение количества ордеров сетки. Но на мой взгляд, работать со структурой немного удобнее, плюс поговаривают, что она обрабатывается быстрее. В этом случае все, что относится к сетке ордеров мы сможем видеть невооруженным глазом по приставке env.

Переходим к функции обработки событий OnInit(). Внутри нее нужно сделать проверку на количество знаков после запятой на торговом счета и осуществить перевод старых пунктов в новые, если это необходимо. Это относится ко всем внешним переменным, которые имеют значения в пунктах.

int OnInit() {

   if (Digits == 3 || Digits == 5) {
      Slippage *= 10;
      TakeProfit *= 10;
      GridDistance *= 10;
      BE_Step *= 10;
   } 
     
   return(INIT_SUCCEEDED);  
}

int OnInit() {

if (Digits == 3 || Digits == 5) {

Slippage *= 10;

TakeProfit *= 10;

GridDistance *= 10;

BE_Step *= 10;

}

return(INIT_SUCCEEDED);

}

Пишем основной код советника внутри функции OnTick()

Наш будущий код будет разбит на три основных блока, расположенными друг за другом в функции OnTick().

Первый блок будет определять сигнал индикатора MACD один раз в свечу, проверять наличие открытых ордеров и, если их нет, открывая первый ордер сетки.
Второй блок будет модифицировать ТП всех ордеров советника, если он еще не выставился, либо по какой-то причине удалился.
Третий, самый обширный блок создан для работы с сеткой ордеров — их анализ, проверка расстояния и открытие новых колен.

Тем не менее, располагаться в коде они будут в порядке 3-2-1. Вначале будет идти анализ сетки, потом модификация и только потом уже открытие первого ордера. Это нужно для правильной логики работы всей программы.

1 Блок: проверка условий на вход первого ордера

Как я уже писал ранее, для определения сигнала на вход мы будем использовать встроенный в Meta Trader индикатор MACD. Данные мы будем брать на первой закрытой свече [1], т.е. нам нет необходимости дергать индюк каждый тик, достаточно импортировать показания 1 раз в свечу. Для запоминания времени открытия свечи мы будем использовать переменную Update_Time.

Импорт данных технического индикатора происходит с помощью функции iMACD. Для того, чтобы понять, что гистограмма индикатора пересекла нулевую отметку нам нужны значения на [1] и [2] свечах. Т.е. для покупок гистограмма на [1] свече должна закрыться выше нуля, а на второй ниже 0. Параметры, передаваемые в функцию:

Имя символа. Берем текущий, т.е. NULL
Таймфрейм графика. Текущий, т.е. 0
Период быстрой средней. Берем из внешних настроек InpFastEMA
Период медленной средней. Из настроек InpSlowEMA
Период сигнальной линии. Из настроек InpSignalSMA
Тип цены. Берем по классике цену закрытия PRICE_CLOSE
Индекс линии индикатора. Данный индикатор имеет два показателя: гистограмму и сигнальную линию. Нам нужен первый, поэтому указываем MODE_MAIN
Сдвиг — номер свечи, с которой нужно получить данные. В нашем случае нам нужно получить данные с [1] и [2] свечей.

После этого необходимо проверить, чтобы в рынке не было открытых ордеров данного направления и данные индикатора подходили под сигнал.

В конце функции OnTick() не забываем прописывать проверку на всевозможные ошибки. На начальных этапах обучения программирования очень важно видеть, что в течении одного тика советник не выдал ни одной ошибки. А если они есть — тут же исправить.

   //1 Блок: проверка условий на вход первого ордера
   if(Update_Time != iTime(NULL,0,0)) { //обновлять данные всех индикаторов раз в период
      Update_Time = iTime(NULL,0,0); //перезаписываем значение переменной для хранения времени текущей свечи
   
      //импорт данных индикатора MACD.
      double MACD1 = iMACD(NULL,0,InpFastEMA,InpSlowEMA,InpSignalSMA,PRICE_CLOSE,MODE_MAIN,1);
      double MACD2 = iMACD(NULL,0,InpFastEMA,InpSlowEMA,InpSignalSMA,PRICE_CLOSE,MODE_MAIN,2);
          
      if(env.count_buy == 0 && MACD1 >= 0 && MACD2 < 0 && MACD1 > MACD2) { //условие для открытия ордера на покупку
         OpenTrade(OP_BUY, 0); //открытие ордера на покупку
      }
      
      if(env.count_sell == 0 && MACD1 <= 0 && MACD2 > 0 && MACD1 < MACD2) { //условие для открытия ордера на продажу
         OpenTrade(OP_SELL, 0); //открытие ордера на продажу
      }
   }

   int Error = GetLastError(); //поиск ошибок по завершению тика
   if(Error != 0) Print("OnTick() Error ",Error,": ",ErrorDescription(Error));

//1 Блок: проверка условий на вход первого ордера

if(Update_Time != iTime(NULL,0,0)) { //обновлять данные всех индикаторов раз в период

Update_Time = iTime(NULL,0,0); //перезаписываем значение переменной для хранения времени текущей свечи

//импорт данных индикатора MACD.

double MACD1 = iMACD(NULL,0,InpFastEMA,InpSlowEMA,InpSignalSMA,PRICE_CLOSE,MODE_MAIN,1);

double MACD2 = iMACD(NULL,0,InpFastEMA,InpSlowEMA,InpSignalSMA,PRICE_CLOSE,MODE_MAIN,2);

if(env.count_buy == 0 && MACD1 >= 0 && MACD2 < 0 && MACD1 > MACD2) { //условие для открытия ордера на покупку

OpenTrade(OP_BUY, 0); //открытие ордера на покупку

}

if(env.count_sell == 0 && MACD1 <= 0 && MACD2 > 0 && MACD1 < MACD2) { //условие для открытия ордера на продажу

OpenTrade(OP_SELL, 0); //открытие ордера на продажу

}

int Error = GetLastError(); //поиск ошибок по завершению тика

if(Error != 0) Print("OnTick() Error ",Error,": ",ErrorDescription(Error));

Открытие ордеров происходит с помощью пользовательской функции OpenTrade с двумя параметрами — направление сделки и мульт торгового лота. Эту функцию мы будем использовать для всех ордеров нашего советника.

Т.к. первый блок открывает самый первый ордер сетки, то множитель отсутствует, и мы передаем ноль. В зависимости от направления будущего ордера мы должны определить:

Цену, по которой будет открытие. Bid для продаж, Ask для покупок
Цвет стрелочки для отображения места открытия ордера на графике.
Комментарий после успешного открытия ордера.
Текущее количество ордеров в заданном направлении
Лот первого ордера сетки
Лот последнего ордера сетки

Переменным структуры мы передадим значения в третьем блоке кода, сейчас нужно просто прописать их в этой функции, чтобы к ней в дальнейшем не возвращаться.

bool OpenTrade(int OP_Type, double mult) { //функция для открытия рыночного ордера  
   
   int counter = 0;
   double lot = Lot, price = 0;
   double first_lot = 0, last_lot = 0;
   color  col_type = clrNONE;
   string op_str = "";
   
   if(OP_Type == OP_BUY) {
      price = Ask; //определение цены для открытия рыночного ордера
      col_type = clrBlue; //определение цвета стрелки ордера
      op_str = "на покупку"; //определение текста для принта
      counter = env.count_buy;
      first_lot = env.firstlotB;
      last_lot  = env.lastlotB; 
   }
   else {
      price = Bid; //определение цены для открытия рыночного ордера
      col_type = clrRed; //определение цвета стрелки ордера
      op_str = "на продажу"; //определение текста для принта
      counter = env.count_sell;
      first_lot = env.firstlotS; 
      last_lot  = env.lastlotS; 
   }
   ... дальнейший код

bool OpenTrade(int OP_Type, double mult) { //функция для открытия рыночного ордера

int counter = 0;

double lot = Lot, price = 0;

double first_lot = 0, last_lot = 0;

color col_type = clrNONE;

string op_str = "";

if(OP_Type == OP_BUY) {

price = Ask; //определение цены для открытия рыночного ордера

col_type = clrBlue; //определение цвета стрелки ордера

op_str = "на покупку"; //определение текста для принта

counter = env.count_buy;

first_lot = env.firstlotB;

last_lot = env.lastlotB;

}

else {

price = Bid; //определение цены для открытия рыночного ордера

col_type = clrRed; //определение цвета стрелки ордера

op_str = "на продажу"; //определение текста для принта

counter = env.count_sell;

first_lot = env.firstlotS;

last_lot = env.lastlotS;

}

... дальнейший код

Ниже с помощью оператора if осуществляется проверка на наличие множителя у передаваемых параметров. Если данная функция запущена из блока работы с сеткой, то мульт будет больше 0. В этом случае нам необходимо определить лот для очередного ордера сетки. Ранее нами была добавлена внешняя переменная Averaging_Level, которая перестает увеличивать торговый лот при достижении определенного колена, поэтому нам необходимо осуществить проверку, что текущий ордер по счету превышает значение параметра Averaging_Level. Если это так, то новый лот будет равен последнему известному значению. Если не так, то определение торгового лота будущего ордера происходит с помощью математической функции MathPow — возведение основания в степень. Данный подход позволяет работать с множителем менее 1.5 для сеток, где начальный лот составляет 0.01 и является более подходящем, чем банальное умножение последнего известного лота на множитель.

   ... прошлый код

   if(mult > 0) { //задаем лот для следующего ордера сетки
      if(Averaging_Level > 0 && counter >= Averaging_Level-1) lot = NormalizeDouble(last_lot, 2);
      else lot = NormalizeDouble(first_lot * MathPow(Multiplier, counter), 2); //увеличиваем лот для сетки
   }
   
   ... дальнейший код

... прошлый код

if(mult > 0) { //задаем лот для следующего ордера сетки

if(Averaging_Level > 0 && counter >= Averaging_Level-1) lot = NormalizeDouble(last_lot, 2);

else lot = NormalizeDouble(first_lot * MathPow(Multiplier, counter), 2); //увеличиваем лот для сетки

}

... дальнейший код

Осталось открыть непосредственно сам ордер по полученным данным. Для большего понимая нумерации колен мы добавим в комментарий к ордеру значение счетчика открытых колен.

   ... прошлый код

   int ticket = OrderSend(Symbol(), OP_Type, lot, price, Slippage, 0, 0, Comments + "(" + IntegerToString(counter+1) + ")", MagicNumber, 0, col_type);
   if(ticket > 0) { //Если ордер был открыт
      Print("Ордер #" + IntegerToString(ticket) + " успешно открыт");
      return(true);
   }
   else { //при ошибке открытия ордера
      int Error = GetLastError();
      if(mult == 0) Update_Time = 0;
      Print("Ошибка открытия ордера ",Error,": ",ErrorDescription(Error));
   }
   return(false);
}

... прошлый код

int ticket = OrderSend(Symbol(), OP_Type, lot, price, Slippage, 0, 0, Comments + "(" + IntegerToString(counter+1) + ")", MagicNumber, 0, col_type);

if(ticket > 0) { //Если ордер был открыт

Print("Ордер #" + IntegerToString(ticket) + " успешно открыт");

return(true);

}

else { //при ошибке открытия ордера

int Error = GetLastError();

if(mult == 0) Update_Time = 0;

Print("Ошибка открытия ордера ",Error,": ",ErrorDescription(Error));

}

return(false);

}

Соединяем код из трех последний примеров в одну функцию и компилируем советник. У вас не должно быть ошибок. Полученный код можно посмотреть на визуализации, но сейчас он не рабочий, поэтому вы увидите кашу из ордеров.

2 Блок: модификация ТП открытых ордеров

Функцию открытия ордеров мы прописали, теперь нужно произвести модификацию Тейк Профита всех сделок, у которых нет целей. Тут нет ничего сложного, мы просто циклом проходимся по всем открытым ордерам нашего советника, учитываем символ, тип ордера и магик номер. Далее если ТП выделенного ордера равен нулю, то идет его расчет и дальнейшая модификация.

При расчете ТП для одного ордера в рынке мы просто берем его цену открытия и прибавляем к ней необходимое значение в пунктах. Но т.к. в данном коде у нас осуществляется работа с сеткой ордеров, у которой один общий ТП, то его расчет нужно производить от уровня безубытка всей корзины. Для этого нам нужны переменный env.avgB и env.avgS, которые мы будем рассчитывать в третьем блоке кода. Сейчас суть проста, если у них есть значения, значит мы учитываем их как уровень БУ. Если же значение отсутствует, значит текущий ордер единственный в этом направлении у советника и расчет нужно вести от его цены открытия.

   //2 Блок: модификация ТП открытых ордеров
   int _OrdersTotal = OrdersTotal();
   for(int pos = _OrdersTotal - 1; pos >= 0; pos--) { //цикл по всем открытым ордерам
      if(!OrderSelect(pos, SELECT_BY_POS, MODE_TRADES)) continue; //выделение ордера для получения его данных
      //проверка, чтобы ордер относился в нашему советнику
      if(OrderType() <= 2 && OrderSymbol() == Symbol() && OrderMagicNumber() == MagicNumber) { 
         if(OrderTakeProfit() == 0) { //если у ордера нет ТП, производим модификацию
            double TP = 0;
            
            if(OrderType() == OP_BUY) {
               double price = (env.avgB > 0 ? env.avgB : OrderOpenPrice());
               TP = NormalizeDouble(price+TakeProfit*Point,Digits);
            }
            else {
               double price = (env.avgS > 0 ? env.avgS : OrderOpenPrice());
               TP = NormalizeDouble(price-TakeProfit*Point,Digits);
            }
             
            if(!OrderModify(OrderTicket(), OrderOpenPrice(), 0, TP, 0, clrNONE)) { //модификация ордера
               int Error = GetLastError();
               Print("Ошибка модификации ордера ",Error,": ",ErrorDescription(Error)); 
            }
            else Print("Ордер #" + IntegerToString(OrderTicket()) + " успешно модифицирован");
         }
      }      
   }
   //1 Блок: проверка условий на вход первого ордера ...

//2 Блок: модификация ТП открытых ордеров

int _OrdersTotal = OrdersTotal();

for(int pos = _OrdersTotal - 1; pos >= 0; pos--) { //цикл по всем открытым ордерам

if(!OrderSelect(pos, SELECT_BY_POS, MODE_TRADES)) continue; //выделение ордера для получения его данных

//проверка, чтобы ордер относился в нашему советнику

if(OrderType() <= 2 && OrderSymbol() == Symbol() && OrderMagicNumber() == MagicNumber) {

if(OrderTakeProfit() == 0) { //если у ордера нет ТП, производим модификацию

double TP = 0;

if(OrderType() == OP_BUY) {

double price = (env.avgB > 0 ? env.avgB : OrderOpenPrice());

TP = NormalizeDouble(price+TakeProfit*Point,Digits);

}

else {

double price = (env.avgS > 0 ? env.avgS : OrderOpenPrice());

TP = NormalizeDouble(price-TakeProfit*Point,Digits);

}

if(!OrderModify(OrderTicket(), OrderOpenPrice(), 0, TP, 0, clrNONE)) { //модификация ордера

int Error = GetLastError();

Print("Ошибка модификации ордера ",Error,": ",ErrorDescription(Error));

}

else Print("Ордер #" + IntegerToString(OrderTicket()) + " успешно модифицирован");

}

//1 Блок: проверка условий на вход первого ордера ...

Данный код вставляем в функцию OnTick выше первого блока.

3 Блок: подсчет ордеров и работа с Мартингейлом

Первые ордера наш советник уже открывает, на следующем тике производит модификацию. Осталось добавить функции построения сетки. Чтобы не захламлять OnTick дополнительным кодом, мы создадим три отдельные функции для получения информации по текущим ордерам, расчета уровня БУ и модификации ордеров сетки. В OnTick в самом начале мы запустим пользовательскую функцию

void OnTick() {
  
   //3 Блок: подсчет ордеров и работа с мартингейлом
   CheckMartingale();

   ... дальнейший код

void OnTick() {

//3 Блок: подсчет ордеров и работа с мартингейлом

CheckMartingale();

... дальнейший код

Пользовательская функция CheckMartingale будет использовать структуру для сохранения данных по ордерам в ее переменные. Вначале мы должны произвести обнуление всех переменных структуры, чтобы старые данные не учитывались в расчете. Для этого воспользуемся общей функцией ZeroMemory.

Далее нам необходимо циклом пройтись по всем открытым ордерам. В зависимости от направления активировать запись их количества в счетчики env.count_buy и env.count_sell. Для того чтобы определить минимальной из лотов открытых ордеров (лота первого ордера сетки) нам придется сравнивать значения лота каждого ордера с минимальным. Для определения времени открытия последнего ордера, его расстояния от текущей цены и лота последнего ордера нам необходимо сравнивать время каждого ордера с самым поздним из известных.

По полученным данным мы определяем если ли вообще ордера в рынке и если да, то больше ли дистанция, пройденная ценой в сторону убытка, чем заданная дистанция GridDistance из настроек. Соответственно, если цена уже ушла на достаточное расстояние от цены открытия последнего ордера мы открываем новое колено сетки с помощью функции OpenTrade, задав ей значение множителя из настроек.

После того как ордер успешно открыт, мы увеличиваем значение счетчика ордеров на единицу и запускаем функцию модификации всех ордеров сетки, чтобы пересчитать уровень БУ и выставить новый, актуальный Тейк Профит.

//+------------------------------------------------------------------+
void CheckMartingale() {
 
   ZeroMemory(env); //обнуляем данные структуры
   
   int _OrdersTotal = OrdersTotal();
   for(int pos = _OrdersTotal - 1; pos >= 0; pos--) {
      if(!OrderSelect(pos, SELECT_BY_POS, MODE_TRADES)) {
         Print(__FUNCTION__ + ": не удалось выделить ордер! " + ErrorDescription(GetLastError()));
	 continue;
      }
      if(OrderType() <= 2 && OrderSymbol() == Symbol() && OrderMagicNumber() == MagicNumber) {
         if(OrderType() == OP_BUY) {
            env.count_buy++;
            
            if(env.firstlotB == 0 || OrderLots() < env.firstlotB) env.firstlotB = OrderLots(); 
            
            if(OrderOpenTime() > env.lasttimeB) {
               env.lasttimeB = OrderOpenTime();
               env.last_distanceB = OrderOpenPrice()-Ask;
               env.lastlotB =  OrderLots();
            }    
         }
         else if(OrderType() == OP_SELL) {
            env.count_sell++;
            
            if(env.firstlotS == 0 || OrderLots() < env.firstlotS) env.firstlotS = OrderLots();

            if(OrderOpenTime() > env.lasttimeS) {
               env.lasttimeS = OrderOpenTime();
               env.last_distanceS = Bid-OrderOpenPrice();
               env.lastlotS =  OrderLots();
            }
         }
      }
   }
     
   if(env.last_distanceB != 0 || env.last_distanceS != 0) { //если есть открытые ордера
      if(env.lasttimeB > 0 && env.last_distanceB >= GridDistance*Point) {
         if(OpenTrade(OP_BUY,Multiplier)) { //Открытие следующего ордера сетки на покупку
            env.count_buy++; //прибавление ордера к счетчику
            Modify_grid(OP_BUY); //модификация целей ордера после открытия
         }
      }
      if(env.lasttimeS > 0 && env.last_distanceS >= GridDistance*Point) {
         if(OpenTrade(OP_SELL,Multiplier)) { //Открытие следующего ордера сетки на продажу
            env.count_sell++; //прибавление ордера к счетчику
            Modify_grid(OP_SELL); //модификация целей ордера после открытия
         }
      }
   }
}

//+------------------------------------------------------------------+

void CheckMartingale() {

ZeroMemory(env); //обнуляем данные структуры

int _OrdersTotal = OrdersTotal();

for(int pos = _OrdersTotal - 1; pos >= 0; pos--) {

if(!OrderSelect(pos, SELECT_BY_POS, MODE_TRADES)) {

Print(__FUNCTION__ + ": не удалось выделить ордер! " + ErrorDescription(GetLastError()));

continue;

}

if(OrderType() <= 2 && OrderSymbol() == Symbol() && OrderMagicNumber() == MagicNumber) {

if(OrderType() == OP_BUY) {

env.count_buy++;

if(env.firstlotB == 0 || OrderLots() < env.firstlotB) env.firstlotB = OrderLots();

if(OrderOpenTime() > env.lasttimeB) {

env.lasttimeB = OrderOpenTime();

env.last_distanceB = OrderOpenPrice()-Ask;

env.lastlotB = OrderLots();

}

else if(OrderType() == OP_SELL) {

env.count_sell++;

if(env.firstlotS == 0 || OrderLots() < env.firstlotS) env.firstlotS = OrderLots();

if(OrderOpenTime() > env.lasttimeS) {

env.lasttimeS = OrderOpenTime();

env.last_distanceS = Bid-OrderOpenPrice();

env.lastlotS = OrderLots();

}

if(env.last_distanceB != 0 || env.last_distanceS != 0) { //если есть открытые ордера

if(env.lasttimeB > 0 && env.last_distanceB >= GridDistance*Point) {

if(OpenTrade(OP_BUY,Multiplier)) { //Открытие следующего ордера сетки на покупку

env.count_buy++; //прибавление ордера к счетчику

Modify_grid(OP_BUY); //модификация целей ордера после открытия

}

if(env.lasttimeS > 0 && env.last_distanceS >= GridDistance*Point) {

if(OpenTrade(OP_SELL,Multiplier)) { //Открытие следующего ордера сетки на продажу

env.count_sell++; //прибавление ордера к счетчику

Modify_grid(OP_SELL); //модификация целей ордера после открытия

}

Функцию открытия ордера OpenTrade мы уже прописали в первом блоке, поэтому нам осталось рассчитать общий уровень БУ и определить новый ТП сетки с помощью пользовательской функции CountGridTP(). Уже по полученным данным модифицировать сетку в функции Modify_grid().

Расчет безубытка происходит с помощью цикла по всем открытым ордерам. Нам нужно узнать суммарную цену лота (Price_Lot), для этого необходимо умножить последовательно лот ордера на его цену открытия. Также нужно определить суммарный лот всех ордеров (SumLots) и их количество (count).

Далее безубыток определяется очень просто делением Price_Lot на SumLots. Данная формула позволит вам узнать ту цену на графике, при достижении которой все ордера можно будет закрыть в ноль.

Стоит уточнить, что эта формула не учитывает своп и комиссии при открытии сделки, поэтому если ордера будут долго находиться в рынке, то уровень БУ будет не совсем корректным, но для нас сейчас это не критично.

В начале урока мы добавили внешнюю переменную BE_Level, отвечающую за номером колена, начиная с которого ТП всех ордеров будет переведен в безубыток с отступом BE_Step. Соответственно после того, как мы узнали уровень БУ, мы узнаем корректный ТП и возвращаем это значение в функцию CountGridTP().

double CountGridTP(int OPType) { //подсчет уровня БУ сетки и нового ТП
   
   int count = 0;
   double Price_Lot=0, SumLots=0;
   
   for(int i=0;i<=OrdersTotal()-1;i++) {
      if(OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
         if(OrderSymbol() != Symbol() || OrderMagicNumber() != MagicNumber || OrderType() != OPType) continue;
         Price_Lot += OrderOpenPrice()*OrderLots();
         SumLots += OrderLots();
         count++;
      }
   }
   
   if(SumLots != 0) {
      //находим уровень БУ
      if(OPType == OP_BUY) env.avgB = Price_Lot/SumLots; 
      else env.avgS = Price_Lot/SumLots; 
      
      double TP_pips = TakeProfit*Point; 
           
      if(BE_Level != 0 && count >= BE_Level) { //выставление безубытка
         Print(__FUNCTION__ + ": Тейк профит корзины пересчитан и будет переведен в безубыток с отступом " + DoubleToStr(BE_Step,0) + " пунктов.");
         TP_pips = BE_Step*Point;
      }   
   
      double NewTP = NormalizeDouble(OPType == OP_BUY ? env.avgB + TP_pips : env.avgS - TP_pips, Digits);
      
      return(NewTP);
   }
   
   return(0);
}

double CountGridTP(int OPType) { //подсчет уровня БУ сетки и нового ТП

int count = 0;

double Price_Lot=0, SumLots=0;

for(int i=0;i<=OrdersTotal()-1;i++) {

if(OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {

if(OrderSymbol() != Symbol() || OrderMagicNumber() != MagicNumber || OrderType() != OPType) continue;

Price_Lot += OrderOpenPrice()*OrderLots();

SumLots += OrderLots();

count++;

}

if(SumLots != 0) {

//находим уровень БУ

if(OPType == OP_BUY) env.avgB = Price_Lot/SumLots;

else env.avgS = Price_Lot/SumLots;

double TP_pips = TakeProfit*Point;

if(BE_Level != 0 && count >= BE_Level) { //выставление безубытка

Print(__FUNCTION__ + ": Тейк профит корзины пересчитан и будет переведен в безубыток с отступом " + DoubleToStr(BE_Step,0) + " пунктов.");

TP_pips = BE_Step*Point;

}

double NewTP = NormalizeDouble(OPType == OP_BUY ? env.avgB + TP_pips : env.avgS - TP_pips, Digits);

return(NewTP);

}

return(0);

}

Переходим к функции модификации ордеров сетки, ведь ТП нами уже рассчитан. В зависимости от передаваемого параметра OP_TYPE мы узнаем количество ордеров, уровень БУ, а также текст для будущей линии безубытка. Да, чтобы сделать данный код более насыщенным, мы добавим функцию отрисовки пунктирной горизонтальной линии на графике draw_level(), которая будет показывать цену где прибыль приблизительно равна нулю.

Далее активируется очередной цикл по всем открытым ордерам, выделение и модификация их ТП на новое значение. Внутри цикла по ордерам мы добавили второй цикл for для модификации (до 5 попыток) на случай, если модификация не пройдет с первого раза.

bool Modify_grid(int OP_TYPE) { //модифицировать сетку ордеров после открытия нового ордера

   double NewTP = CountGridTP(OP_TYPE); //подсчет нового ТП и уровня БУ

   int cnt = (OP_TYPE == OP_BUY ? env.count_buy : env.count_sell); 
   string be_level = (OP_TYPE == OP_BUY ? "be_level_buy" : "be_level_sell");
   double avg = (OP_TYPE == OP_BUY ? env.avgB : env.avgS);
   
   //рисуем линию БУ
   if(cnt > 1) draw_level(be_level, avg, clrDarkGoldenrod);
   else draw_level(be_level, 0, clrNONE);
   
   if(NewTP > 0) {
      for(int i=0;i<=OrdersTotal()-1;i++) {
         if(!OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) continue;
         if(OrderSymbol() != Symbol() || OrderMagicNumber() != MagicNumber || OrderType() != OP_TYPE) continue;
         if(OrderTakeProfit() != NewTP) {
            for(int k=0;k<5;k++) {
               if(OrderModify(OrderTicket(), OrderOpenPrice(), 0, NewTP, 0, clrNONE)) { 
                  break; //прерывание цикла
               } 
               RefreshRates();
               Sleep(3000);
            }
         }
      }
   }
   
   return(false);
}

bool Modify_grid(int OP_TYPE) { //модифицировать сетку ордеров после открытия нового ордера

double NewTP = CountGridTP(OP_TYPE); //подсчет нового ТП и уровня БУ

int cnt = (OP_TYPE == OP_BUY ? env.count_buy : env.count_sell);

string be_level = (OP_TYPE == OP_BUY ? "be_level_buy" : "be_level_sell");

double avg = (OP_TYPE == OP_BUY ? env.avgB : env.avgS);

//рисуем линию БУ

if(cnt > 1) draw_level(be_level, avg, clrDarkGoldenrod);

else draw_level(be_level, 0, clrNONE);

if(NewTP > 0) {

for(int i=0;i<=OrdersTotal()-1;i++) {

if(!OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) continue;

if(OrderSymbol() != Symbol() || OrderMagicNumber() != MagicNumber || OrderType() != OP_TYPE) continue;

if(OrderTakeProfit() != NewTP) {

for(int k=0;k<5;k++) {

if(OrderModify(OrderTicket(), OrderOpenPrice(), 0, NewTP, 0, clrNONE)) {

break; //прерывание цикла

}

RefreshRates();

Sleep(3000);

}

return(false);

}

Переходим к функции отрисовки горизонтальной линии draw_level(). У функции есть три параметра: наименование объекта (разное для покупок и продаж), цена на которой линия будет располагаться и ее цвет. Объект горизонтальная линия имеет тип OBJ_HLINE. После открытия нового колена сетки эта линия должна перерисовываться на цену env.avgB или env.avgS. Если же переменной price задать цену, равную нулю, то линия просто удалится с графика. С помощью свойств OBJPROP_PRICE, OBJPROP_STYLE и OBJPROP_COLOR линии задается цена, ее стиль и цвет:

void draw_level(string name, double price, color clr){
   
   if(price<=0){
      if(ObjectFind(0,name) != -1) ObjectDelete(0,name);
   }
   else{
      if(ObjectFind(0,name) < 0) ObjectCreate(0,name, OBJ_HLINE, 0, 0, price); 
      else ObjectSetDouble(0,name, OBJPROP_PRICE, price);
      ObjectSetInteger(0,name, OBJPROP_STYLE, STYLE_DOT);
      ObjectSetInteger(0,name, OBJPROP_COLOR, clr);
   }
}

void draw_level(string name, double price, color clr){

if(price<=0){

if(ObjectFind(0,name) != -1) ObjectDelete(0,name);

}

else{

if(ObjectFind(0,name) < 0) ObjectCreate(0,name, OBJ_HLINE, 0, 0, price);

else ObjectSetDouble(0,name, OBJPROP_PRICE, price);

ObjectSetInteger(0,name, OBJPROP_STYLE, STYLE_DOT);

ObjectSetInteger(0,name, OBJPROP_COLOR, clr);

}

Так как мы должны удалять эту линию каждый раз, когда сетка ордеров закрывается по ТП, то ниже функции третьего блока CheckMartingale() прописываем вызов функции создания линии с нулевым значением, когда количество ордеров равно нулю.

   //3 Блок: подсчет ордеров и работа с мартингейлом
   CheckMartingale(); 
   
   //удаляем линию БУ сетки с графика при отстуствии ордеров
   if(env.count_buy == 0) draw_level("be_level_buy", 0, clrNONE);
   if(env.count_sell == 0) draw_level("be_level_sell", 0, clrNONE);
   
   //2 Блок: модификация ТП открытых ордеров
   ...

//3 Блок: подсчет ордеров и работа с мартингейлом

CheckMartingale();

//удаляем линию БУ сетки с графика при отстуствии ордеров

if(env.count_buy == 0) draw_level("be_level_buy", 0, clrNONE);

if(env.count_sell == 0) draw_level("be_level_sell", 0, clrNONE);

//2 Блок: модификация ТП открытых ордеров

...

Также мы должны удалить эти линии с графика после деинициализации советника.

//+------------------------------------------------------------------+
void OnDeinit(const int reason) {

   draw_level("be_level_buy", 0, clrNONE);
   draw_level("be_level_sell", 0, clrNONE);
   
}

//+------------------------------------------------------------------+

void OnDeinit(const int reason) {

draw_level("be_level_buy", 0, clrNONE);

draw_level("be_level_sell", 0, clrNONE);

}

Если вы запутались с порядком расположения блоков и функций внутри кода, то я вас не виню. Пример урока как всегда во вложении в самом конце статьи.

На этом все, код готов, можно компилировать. Давайте посмотрим, как ведет полученный код себя на графике:

Сделаем пробный прогон в тестере стратегий:

Все работает, как и задумывалось, значит процесс кодинга можно считать успешным.

Стоит заметить, что торговля Мартингейлом является опасным методом торговли на финансовом рынке Форекс (да и на любом другом), поэтому я вам крайне не рекомендую пробовать этот советник на реальных счетах. У нас получился, конечно, не примитивный Ilan 1.6, но все же и не Грааль. Если же этот бот засел вам в душу, то вначале необходимо провести оптимизацию с качественными котировками, плавающим спредом и определить максимальную просадку на истории и корректно рассчитать необходимый депозит. Предупрежден — значит вооружен!

Заключение

Поздравляю тех, кто дочитал текст этого урока до конца, а не просто пролистал его за минуту. Вы прокачали свою выносливость на +30 и научились создавать свой первый советник с функцией построения сетки ордеров по методу Мартингейл. Познали азы работы со структурой, определения уровня безубытка группы ордеров, а также создали горизонтальные объекты на графике.

Хотя данная статья и получилась вполне объемной на текст, данный советник по системе Мартингейл является очень простым по своей логике. 300 строк кода для такой сложной системы это очень даже мало. Для вас же этот шаблон советника mql4 может стать будущим черновиком для действительно интересного продукта. Как вариант, вы можете заменить логику входа первого ордера, изменить статический шаг сетки на динамический, добавить в код АвтоММ и фильтр времени торговли, активировать предварительный выход по сигналам сторонних индикаторов, добавить горизонтальную линию будущего ордера сетки, сделать возможность частичного закрытия крайних ордеров сетки и т.д. Тут все ограничивается только вашим полетом мыслей.

Если вы хотите попробовать в своей торговле действительно навороченный код, то рекомендую вам ознакомиться с нашим платным советником Night Hawk. Данный мартингейл сеточник писался мною 1,5 года и его код занимает 2100 строк, что очень даже внушительно.

На этом все, подписывайтесь на нашу рассылку. Всем профитов!

Блог для успешных трейдеров на рынке Форекс. Полезный сайт о Forex — DaVinci FX Group.

Вернуться назад

Предыдущая запись

3.2 Пишем советник, торгующий по Стохастику в заданное время

Следующая запись

3.4 Импорт данный стороннего индикатора в советник iCustom

6 комментариев. Оставить новый

Andrei
17.04.2021 19:47

Скажите как поставить ограничение на колено! Мне вот надо 4 к примеру, а он открывает сколько балансу позволяет!

Ответить
- admin
  17.04.2021 20:51
  
  Добрый вечер. Можно ввести внешнюю переменную MaxLevels и давить ее в 167 и 173 строчки советника.
  
  C++
  
  if(env.lasttimeB > 0 && env.last_distanceB >= GridDistance*Point && env.count_buy < MaxLevels) {
  
  0
  
  if(env.lasttimeB > 0 && env.last_distanceB >= GridDistance*Point && env.count_buy < MaxLevels) {
  
  C++
  
  if(env.lasttimeS > 0 && env.last_distanceS >= GridDistance*Point && env.count_sell < MaxLevels) {
  
  0
  
  if(env.lasttimeS > 0 && env.last_distanceS >= GridDistance*Point && env.count_sell < MaxLevels) {
  
  Ответить
- Олег
  10.06.2021 09:30
  
  Здравствуйте! Вы писали что на м15, нужна работа советника на тф м1
  
  Ответить
  - admin
    10.06.2021 12:01
    
    Добрый. Советник будет работать на любом ТФ. Для примера был выбран М15.
    
    Ответить
Александр
18.09.2022 22:14

Здравствуйте. Подскажите в советнике по разделу 3.3 в какой строчке и как прописать, чтобы по тренду он тоже открывал?

Ответить
- Валерия
  25.09.2022 19:01
  
  Здравствуйте! Этот советник нуждается в полной переработки блоков 2 и 3, чтобы он торговал и по тренду и против тренда одновременно. Плюс нужно изменить структуру. В нескольких строках не опишешь.
  
  Ответить