Наши рекомендации:

2.8 Пишем пользовательский индикатор-гистограмму волатильности периода Н1

Содержание

Доброго времени суток!

В этом уроке мы создадим индикатор-гистограмму в отдельном окне для определения средней волатильности. Для этого мы используем период график H1, чтобы точно видеть, какое движением в среднем проходит цена в пунктах за каждый анализируемый час. Цель этого урока: повторить уже пройденный материал, проанализировать бары на истории, а также научиться использовать буфер гистограммы.

Создаем индикатор волатильности

В редакторе MetaEditor жмем Файл -> Создать -> Пользовательский индикатор. Задаем все настройки по умолчанию, жмем далее, в окне параметров отображения ставим галочку «индикатор в отдельном окне«, а также создаем два отдельных буфера. Первый будет иметь тип гистограммы для расчета волатильности по часам, а второй — линия, чтобы видеть суммарное изменение волатильности всего графика.

Созданный код будет иметь следующий вид:

//+------------------------------------------------------------------+
//|                                     2.8 Volatility indicator.mq4 |
//|                                   Copyright (c) DaVinci FX Group |
//|                                      https://www.davinci-fx.com/ |
//+------------------------------------------------------------------+
#property copyright "Copyright (c) DaVinci FX Group"
#property link      "https://www.davinci-fx.com/"
#property version   "1.00"
#property strict
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_plots   2
//--- plot Volatility
#property indicator_label1  "Volatility"
#property indicator_type1   DRAW_HISTOGRAM
#property indicator_color1  clrCoral
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- plot VolatilitySum
#property indicator_label2  "VolatilitySum"
#property indicator_type2   DRAW_LINE
#property indicator_color2  clrYellow
#property indicator_style2  STYLE_SOLID
#property indicator_width2  1
//--- indicator buffers
double VolatilityBuffer[];
double VolatilitySumBuffer[];

//+------------------------------------------------------------------+

//| 2.8 Volatility indicator.mq4 |

//| Copyright (c) DaVinci FX Group |

//| https://www.davinci-fx.com/ |

//+------------------------------------------------------------------+

#property copyright "Copyright (c) DaVinci FX Group"

#property link "https://www.davinci-fx.com/"

#property version "1.00"

#property strict

#property indicator_separate_window

#property indicator_buffers 2

#property indicator_plots 2

//--- plot Volatility

#property indicator_label1 "Volatility"

#property indicator_type1 DRAW_HISTOGRAM

#property indicator_color1 clrCoral

#property indicator_style1 STYLE_SOLID

#property indicator_width1 1

//--- plot VolatilitySum

#property indicator_label2 "VolatilitySum"

#property indicator_type2 DRAW_LINE

#property indicator_color2 clrYellow

#property indicator_style2 STYLE_SOLID

#property indicator_width2 1

//--- indicator buffers

double VolatilityBuffer[];

double VolatilitySumBuffer[];

Сразу же изменим толщину гистограммы до трех, чтобы было пожирнее и весомее.

#property indicator_width1  3

0	#property indicator_width1 3

Все дальнейшие строки кода я буду писать в той последовательности, в которой они есть в готовом коде, т.е. сверху вниз.

Далее определимся с количеством дней для анализа свечей. Возьмем ни много ни мало 50 дней. Но, чтобы иметь возможность менять это значение, вынесем его во внешние настройки индикатора.

extern int CalculatedDays = 50; //Calculated Days

0	extern int CalculatedDays = 50; //Calculated Days

Добавим две переменные на глобальном уровне: PipsDivided для перевода пунктов в старый вариант отображения (про эту переменную я писал подробнее в этом уроке). Переменная TimeNewBar будет нужна для сохранения времени открытия текущей свечи.

int PipsDivided = 1;
datetime TimeNewBar = 0;

0 1	int PipsDivided = 1; datetime TimeNewBar = 0;

Переходим к функции обработки событий OnInit. В нее нужно добавить проверку на количество знаков на счете брокера для множителя PipsDivided. Также перевести дни для анализа в часы, т.к. нами будет использоваться часовой график. Можно было сразу задать время в настройках в часах, но в днях это делать просто удобнее.

if (Digits == 3 || Digits == 5) PipsDivided = 10;
CalculatedDays *=24;

0 1	if (Digits == 3 \|\| Digits == 5) PipsDivided = 10; CalculatedDays *=24;

Дополнительно для пользователей, который захотят установить индикатор на любой ТФ, отличный от Н1 мы сделаем проверку ТФ графика. Если она не проходит — индикатор напишет об этом в журнале и самоликвидируется с графика.

if(Period() != PERIOD_H1) { Print("Измените период на Н1"); return(INIT_FAILED); }

0	if(Period() != PERIOD_H1) { Print("Измените период на Н1"); return(INIT_FAILED); }

Переходим к основной функции OnCalculate. Первой же проверкой нужно узнать, подгрузились ли все необходимые бары на график. И если нет, то принудительно перерисуем график. Возьмем для построения гистограммы последние 3000 баров, т.е. 3000 часов или 125 дней. Т.к. для каждой свечи анализ будет проходить только за последние 50 дней, то вычтем это значение из общего числа баров.

int maxbars = 3000-CalculatedDays;
if(maxbars > Bars) { ChartRedraw(); return(0); }

0 1	int maxbars = 3000-CalculatedDays; if(maxbars > Bars) { ChartRedraw(); return(0); }

Так как нас интересует волатильность по уже закрытым свечам, то нет смысла делать все перерасчеты каждый тик. Для этого с помощью условного оператора сделаем проверку на текущее время открытой свечи. Если оно будет совпадать с сохраненным в памяти временем, то мы завершаем работу с функцией OnCalculate на этом тике. В итоге построение гистограммы будет обновляться один раз в час при открытии новой свечи.

   if(TimeNewBar == iTime(NULL,PERIOD_CURRENT,0)) return(rates_total); 
   TimeNewBar = iTime(NULL,PERIOD_CURRENT,0); //сохраняем текущее время

0 1	if(TimeNewBar == iTime(NULL,PERIOD_CURRENT,0)) return(rates_total); TimeNewBar = iTime(NULL,PERIOD_CURRENT,0); //сохраняем текущее время

Чтобы рассчитать волатильность для каждой свечи, нам нужно ввести две пары переменных. Первые две переменные будут считать суммарное количество анализируемых свечей, а также сумму длин этих свечей от цены открытия до цены закрытия. Это нужно для того, чтобы поделить одно на другое и узнать волатильность для текущей свечи. Вторая пара нужна, чтобы узнать сумму свечей на заданный час и сумму их значений.

Для анализа свечей мы воспользуемся оператором циклом for. Параметры для подсчета волатильности вообще всех свечей необходимо объявлять вне цикла, чтобы они не обнулились при следующей итерации. По этим значениям будет строиться желтая линия индикатора. Соответственно параметры для свечей каждого часа задаются внутри цикла.

   int cnt_all = 0;
   double sum_vol = 0;

   for(int i=0;i<maxbars;i++) {
      int cnt = 0;
      double vol = 0;
   }

int cnt_all = 0;

double sum_vol = 0;

for(int i=0;i<maxbars;i++) {

int cnt = 0;

double vol = 0;

}

Далее нам необходимо создать второй цикл for внутри существующего. Суть первого цикла в том, чтобы пробежать по всем 3000 свечам и построить гистограмму и линию, а второго, чтобы рассчитать эту волатильность для каждой отдельной свечи за CalculatedDays дней. Второй цикл будет иметь вид:

      for(int j=i;j<i+CalculatedDays;j++) {
         
      }

for(int j=i;j<i+CalculatedDays;j++) {

}

Он начинается свой отчет с переменной i вышестоящего цикла, т.е. с выделенной свечи и идет он ровно обозначенное количество свечей подряд. Второе выражение i+CalculatedDays должно вести отчет от последней анализируемой свечи цикла первого уровня, т.е. i.

Чтобы не выйти за пределы массива из-за недостатка баров на графике нам необходимо сделать проверку. Если свеча на очередной итерации превысит максимально допустимое количество баров — второй цикл прерывается.

      if(j >= maxbars) break;

0	if(j >= maxbars) break;

Расчет длины свечи прост, необходимо лишь вычесть от цены открытия свечи ее цену закрытия, перевести все в пункты и возвести в модуль, т.к. нам все равно в каком направлении двигалась анализируемая свеча.

      double CandleSize = MathAbs(Open[j]-Close[j])/Point/PipsDivided;

0	double CandleSize = MathAbs(Open[j]-Close[j])/Point/PipsDivided;

Есть вам необходимо знать движения с учетом хвостов (теней), то просто измените цены Open, Close на High, Low.

Следующим условием будет проверка времени анализируемой свечи внутреннего цикла со временем свечи первого цикла. Если оно совпадает, значит час текущей, анализируемой свечи совпадает с часом прошлых свечей на истории. Нам нужно только обновить данные в памяти переменных длины свечей и счетчика.

     if(TimeHour(Time[i]) == TimeHour(Time[j])) {
        vol += CandleSize;
        cnt++;
     }

if(TimeHour(Time[i]) == TimeHour(Time[j])) {

vol += CandleSize;

cnt++;

}

Помимо этого, нам не важно время свечи для общей линии волатильности, поэтому ниже просто дописываем ее данные в переменные первой пары.

     sum_vol += CandleSize;
     cnt_all++;

0 1	sum_vol += CandleSize; cnt_all++;

С циклом внутри цикла разобрались. Осталось передать данные в массивы двух буферов, если счетчики были не нулевые для текущей итерации.

   if(cnt > 0) VolatilityBuffer[i] = NormalizeDouble(vol/cnt,1); 
   if(cnt_all > 0) VolatilitySumBuffer[i] = NormalizeDouble(sum_vol/cnt_all,1);

0 1	if(cnt > 0) VolatilityBuffer[i] = NormalizeDouble(vol/cnt,1); if(cnt_all > 0) VolatilitySumBuffer[i] = NormalizeDouble(sum_vol/cnt_all,1);

Если вы все правильно написали, то полученный индикатор будет иметь следующий вид:

Желтая, почти горизонтальная линия будет показывать волатильность за 50 дней всех свечей на графике, тогда как оранжевые гистограммы будут показывать, какая средняя волатильность была за каждый час этих 50 дней. Общая тенденция не особо заметна глазу, но если отдалишь график, то можно увидеть, как волатильность изменяется из-за дня в день.

Создаем текстовый лейбл

Осталось добавить последний штрих. Так как мы уже умеет создавать графические объекты, почему бы цифрами не обозначить волатильность на каждой свече в пунктах. Для этого создадим пользовательскую функцию TextCreate, которая будет создавать объект текст OBJ_TEXT.

//+------------------------------------------------------------------+
bool TextCreate(const long              chart_ID=0,               // ID графика 
                const string            name="Text",              // имя объекта 
                const int               sub_window=0,             // номер подокна 
                datetime                time=0,                   // время точки привязки 
                double                  price=0,                  // цена точки привязки 
                const string            text="Text",              // сам текст 
                const string            font="Arial",             // шрифт 
                const int               font_size=9,              // размер шрифта 
                const color             clr=clrRed,               // цвет 
                const double            angle=0.0,                // наклон текста 
                const ENUM_ANCHOR_POINT anchor=ANCHOR_LEFT_UPPER) // способ привязки 
{ 
   ResetLastError(); 
   
   if(ObjectFind(chart_ID,name) == -1) { //если объект не найден - создаем новый
      if(!ObjectCreate(chart_ID,name,OBJ_TEXT,sub_window,time,price)) { //создаем новый объект
         Print(__FUNCTION__,": не удалось создать объект \"Текст\"! Код ошибки = ",GetLastError()); 
         return(false); 
      } 
   }

   ObjectSetDouble(chart_ID,name,OBJPROP_PRICE,price); //назначаем объекту цену
   ObjectSetInteger(chart_ID,name,OBJPROP_TIME,time);  //назначаем объекту время
   ObjectSetString(chart_ID,name,OBJPROP_TEXT,text);   //текст для объекта
   ObjectSetString(chart_ID,name,OBJPROP_FONT,font);   //шрифт
   ObjectSetInteger(chart_ID,name,OBJPROP_FONTSIZE,font_size); //размер шрифта
   ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle); //угол наклона шрифта
   ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,anchor); //угол привязки
   ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr); //цвет объекта

   return(true); 
}

//+------------------------------------------------------------------+

bool TextCreate(const long chart_ID=0, // ID графика

const string name="Text", // имя объекта

const int sub_window=0, // номер подокна

datetime time=0, // время точки привязки

double price=0, // цена точки привязки

const string text="Text", // сам текст

const string font="Arial", // шрифт

const int font_size=9, // размер шрифта

const color clr=clrRed, // цвет

const double angle=0.0, // наклон текста

const ENUM_ANCHOR_POINT anchor=ANCHOR_LEFT_UPPER) // способ привязки

{

ResetLastError();

if(ObjectFind(chart_ID,name) == -1) { //если объект не найден - создаем новый

if(!ObjectCreate(chart_ID,name,OBJ_TEXT,sub_window,time,price)) { //создаем новый объект

Print(__FUNCTION__,": не удалось создать объект \"Текст\"! Код ошибки = ",GetLastError());

return(false);

}

ObjectSetDouble(chart_ID,name,OBJPROP_PRICE,price); //назначаем объекту цену

ObjectSetInteger(chart_ID,name,OBJPROP_TIME,time); //назначаем объекту время

ObjectSetString(chart_ID,name,OBJPROP_TEXT,text); //текст для объекта

ObjectSetString(chart_ID,name,OBJPROP_FONT,font); //шрифт

ObjectSetInteger(chart_ID,name,OBJPROP_FONTSIZE,font_size); //размер шрифта

ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle); //угол наклона шрифта

ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,anchor); //угол привязки

ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr); //цвет объекта

return(true);

}

Останавливаться на этом коде подробно не буду, мы проходили создания объектов в этом уроке.

Добавим эту функцию после кода заполнения буфера данных гистограммы.

   if(cnt > 0) {
      VolatilityBuffer[i] = NormalizeDouble(vol/cnt,1);
      TextCreate(0,"DV|Vol"+IntegerToString(i),ChartWindowFind(),Time[i],VolatilityBuffer[i]+1,
         DoubleToString(VolatilityBuffer[i],1),"Arial",7,clrCornflowerBlue,90,ANCHOR_CENTER);
   }

if(cnt > 0) {

VolatilityBuffer[i] = NormalizeDouble(vol/cnt,1);

TextCreate(0,"DV|Vol"+IntegerToString(i),ChartWindowFind(),Time[i],VolatilityBuffer[i]+1,

DoubleToString(VolatilityBuffer[i],1),"Arial",7,clrCornflowerBlue,90,ANCHOR_CENTER);

}

В функцию TextCreate мы передаем ID графика, имя объекта, номер подокна, время для построения и значение бара гистограммы с отступом в 1 пункт вверх, текст в виде цифр, тип шрифта, размер шрифта, цвет объекта, угол наклона в 90 градусов, а также точку привязки к объекту.

Конечный код функции OnCalculate будет иметь вид:

int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
{
   int maxbars = 3000-CalculatedDays;
   if(maxbars > Bars) { ChartRedraw(); return(0); }
   
   if(TimeNewBar == iTime(NULL,PERIOD_CURRENT,0)) return(rates_total); 
   TimeNewBar = iTime(NULL,PERIOD_CURRENT,0); //сохраняем текущее время
   
   int cnt_all = 0;
   double sum_vol = 0;

   for(int i=0;i<maxbars;i++) {
      int cnt = 0;
      double vol = 0;
       
      for(int j=i;j<i+CalculatedDays;j++) {
         if(j >= maxbars) break;
         double CandleSize = MathAbs(Open[j]-Close[j])/Point/PipsDivided;
         if(TimeHour(Time[i]) == TimeHour(Time[j])) {
            vol += CandleSize;
            cnt++;
         }
         sum_vol += CandleSize;
         cnt_all++;
      }
      
      if(cnt > 0) {
         VolatilityBuffer[i] = NormalizeDouble(vol/cnt,1);
         TextCreate(0,"DV|Vol"+IntegerToString(i),ChartWindowFind(),Time[i],VolatilityBuffer[i]+1,
            DoubleToString(VolatilityBuffer[i],1),"Arial",7,clrCornflowerBlue,90,ANCHOR_CENTER);
      }   
      if(cnt_all > 0) VolatilitySumBuffer[i] = NormalizeDouble(sum_vol/cnt_all,1);
   }

   return(rates_total);
}

int OnCalculate(const int rates_total,

const int prev_calculated,

const datetime &time[],

const double &open[],

const double &high[],

const double &low[],

const double &close[],

const long &tick_volume[],

const long &volume[],

const int &spread[])

{

int maxbars = 3000-CalculatedDays;

if(maxbars > Bars) { ChartRedraw(); return(0); }

if(TimeNewBar == iTime(NULL,PERIOD_CURRENT,0)) return(rates_total);

TimeNewBar = iTime(NULL,PERIOD_CURRENT,0); //сохраняем текущее время

int cnt_all = 0;

double sum_vol = 0;

for(int i=0;i<maxbars;i++) {

int cnt = 0;

double vol = 0;

for(int j=i;j<i+CalculatedDays;j++) {

if(j >= maxbars) break;

double CandleSize = MathAbs(Open[j]-Close[j])/Point/PipsDivided;

if(TimeHour(Time[i]) == TimeHour(Time[j])) {

vol += CandleSize;

cnt++;

}

sum_vol += CandleSize;

cnt_all++;

}

if(cnt > 0) {

VolatilityBuffer[i] = NormalizeDouble(vol/cnt,1);

TextCreate(0,"DV|Vol"+IntegerToString(i),ChartWindowFind(),Time[i],VolatilityBuffer[i]+1,

DoubleToString(VolatilityBuffer[i],1),"Arial",7,clrCornflowerBlue,90,ANCHOR_CENTER);

}

if(cnt_all > 0) VolatilitySumBuffer[i] = NormalizeDouble(sum_vol/cnt_all,1);

}

return(rates_total);

}

Все, индикатор готов. Теперь все смотрится куда гармоничнее.

Если повнимательнее посмотреть на бары гистограммы, то можно увидеть простую закономерность: ночью, начиная с 22 часов до 7 утра рынок очень спокойный, тогда как в Американскую и Лондонскую торговые сессии график максимально волатильный. А значит во флете рынок находится больше ночью, чем днем. Наша команда использует данную особенность рынка в наших советниках Night Hawk и Sakura.

Заключение

В этом уроке мы создали небольшой индикатор (всего 131 строка), который определяет как почасовую, так и общую волатильность на графике терминала MetaTrader 4. Закрепили ранее полученную информацию и немного приблизились к званию «гуру» кодинга.

В свое время я написал для нашего сайта индикатор волатильности Truly Volatility по подобной логике. Единственное отличие его в том, что он также умеет определять волатильность по дням внутри рабочей недели. Я думаю, что зная основы, вам не составит труда повторить это в данном код при необходимости.

На этом все, всем профитов!